The Miscelaneous Mean Field Potential (MMFP) Commands
The commands in this section are primarily used for setting up special
restraining potentials on some or all of the atoms. The key word MMFP is used
to enter the MMFP environement. In the MMFP environment, all miscelaneous
commands (label, goto, if, etc...), and string substitutions (with @1,
@2, etc...) are supported.
The key word END returns to the main parser. The restraining potentials are
used in all energy calculations, unless SKIP is used (see *note
select:energy.doc). The subcommand RESET clears the potential.
This module is still under developement and only the subcommand
GEO is released. The subcommand GEO (standing for geometrical) is used
to setup various restraining potential (spherical, planar or cyclindrical
restraints) on some or all atoms. The selection specification should be
at the end of the command. The default atom selection includes all atoms.
Future subcommands will include continuum electrostatic reaction field
and solvent mean field potentials. Expected date of release is Spring 1994.
* Menu:
* Syntax:: Syntax of the MMFP commands
* Details:: Descriptions of the GEO subcommands
* Examples:: Examples of GEO subcommands
* Substitutions:: Description and usage of substitution values
Syntax of basic MMFP commands
GEO reset
GEO [maxgeo INTE] [shape_specification] [position_spec] [RCM]
[potential_spec] [atom_selection] [ DISTANCE atom_selection]
[ ANGLE atom_selection ]
[ DIHEDRAL atom_selection ]
SSBP reset
SSBP [atom_selection] [atom_selection] [ssbp_specification]
BHEL [atom_selection]
SHEL [atom_selection] [shell_options-specification]
shape_specification:== { [SPHERE] } [XREF real] [YREF real] [ZREF real]
{ CYLINDER } [XDIR real] [YDIR real] [ZDIR real]
{ PLANAR }
potential_spec:== { HARMonic } { INSIDE } [FORCE real] [DROFF real]
{ QUARtic } { OUTSIDE } [P1 real] [P2 real]
{ EXPOnent } { SYMMETRIC }
{ GAUSsian }
ssbp_pecification:== KIRKWOOD NMULT [integer (15)] [DIEC real] [RADI real]
[DRDIE real] CAVITY HSR ANGU
shell_options-specification:== DRSH [real (5.0)] RELA [real (0.0005)]
FREF [real (0.9)]
RSLV [real (0.0)] FOCO [real (3.0)]
atom-selection:== (see *note select:(select.doc).)
Details of basic MMFP commands
1) GEO RESET
Cancels all restraints in GEO free all space allocated on the HEAP
2) GEO [MAXGEO int]
Allocate space on the HEAP to be used for all subsequent GEO potential terms.
By default, MAXGEO is set to NATOM unless specified. The MMFP subroutine calls
WRNDIE if there is not enough space allocated.
3) RCM key word
With the keyword RCM any restraints is not applied to each individual
atoms of a selection but applied to the center of mass of the selected atoms.
5) [shape_specification]
The shape of the potential is chosen from SPHERE, CYLINDER or PLANE key words,
SPHERE is the default. The shape specification gives the origin
(XREF, YREF, ZREF) and the orientation (XDIR, YDIR, ZDIR) of a vector
such that a sphere, plane or cylinder may be defined. Using the
shape_specification the potential is calculated from the
general distance from a (x,y,z) reference point (SPHERE), distance from
an axis (CYLINDER) or distance from a plane (PLANE). By default, all
values are zero and the origin of the boundary is at (0.0,0.0,0.0).
If the shape of the boundary requires a unit vector (true for cylinder
and plane), and no values are given the subroutine will call WRNDIE.
6) [potential_spec] [HARMonic]
[QUARtic]
[EXPOnential]
[GAUSsian]
The potential specification has a number of
parameters: [FORCE real] is the amplitude of the potential term
[P1 real] is a parameter used in the quartic potential
[P2 real] unused parameter
[DROFF rea] is an offset distance such that GEO(r) = 0 if r<droff
[INSIDE] the potential used only for r-droff<0
[OUTSIDE] the potential used is only for r-droff>0
[SYMMETRIC] the potential used is for |r-droff|
They determine which kind of potential function will be used in combination
with the geometrical shape. The default is a harmonic potential. A fourth
order polynomial can be used with the key word QUARTIC, the potential has
the form: GEO(r) = FORC*DELTA**2*(DELTA**2-P1), with DELTA=(R-DROFF).
Using the parameters [FORCE 0.2 P1 2.25] the QUARTIC potential can be used
to setup a spherical boundary potential with a well depth of -0.25 kcal/mol
at r=DROFF+1 followed by a smoothly rising repulsion. Such potential is
appropriate for a water sphere of radius DROFF+1.5 and is very similar
to that used in SBOUND, see *note sbound:(sbound.doc).
The key word EXPO defines a exponential potential to mimic interfacial
solvation effects:
= HALF*FORC*EXP(-DELTA/P1), for r > DROFF
= FORC*(1 - HALF*EXP(+DELTA/P1), for r < DROFF
When defined in combination with PLANE shape_specification, this potential
reproduces the "hydrophobic" potential used for transmembrane polypeptide
by O. Edholm. and F. Jahnig, Biophys. Chem. 30, 279-292 (1988).
The key word GAUSS defines a similar gaussian potential to mimic interfacial
solvation effects. The parameter P1 gives the width of the interface.
7) DISTANCE key word With the keyword DISTANCE a restraint is setup
between two sets of atoms or between their center of mass if the key
word RCM is used. A second atom selection must be specified.
8) ANGLE keyword With the keyword ANGLE a restraint is setup between 3
sets of atoms or their center of masses if the keyword RCM is
used. Three sets of atom selections must be made, note that the force
constant is per radian**2 and NOT per degree**2 even though the DROFF
variable (angle constraint) is to be specified in degrees
9) DIHEDRAL keyword With the keyword DIHEDRAL a restraint is setup
between 4 sets of atoms or their center of masses if the keyword RCM
is used. Four sets of atom selections must be made, note that the
force constant is per radian**2 and NOT per degree**2 even though the
DROFF variable (dihedral constraint) is to be specified in degrees
10) SSBP key word
Stands for Spherical Solvent Boundary Potential. Current implementation of
the method described in Beglov & Roux, J. Chem. Phys., 100:9050 (1994).
The method follows from a rigorous reduction of the multi-dimensional
configuration integral from N solvent molecules (10**23) to "n" solvent
molecules (e.g., 1 to 1000).
The SSBP potential corresponds to a constant temperature and constant
pressure system. The non-bonded interactions must be treated with EXTENDED
electrostatics otherwise the system is unstable. There are several
contributions to the boundary potential of mean force: HSR (hard sphere
restriction) is a term setting the external pressure and surface tension;
CAVITY ressembles to the standard stochastic boundary potential and
corresponds to the van der Waals interactions; KIRKWOOD is the multipolar
expansion for the reaction field due to a dielectric continuum surrounding a
cavity containing a charge distribution; ANGU is an angular correction that
works for three sites water models and is used to restore the isotropic
angular distribution near the edge of the sphere. The variable radius of
the sphere is calculated on the fly and does not need to be specified.
The first atom selection flags the atoms for which the VDW and the ANGU
potentials are applied. It also determines the radius of the boundary sphere.
The second selection is optional. If present it flags those atoms that
determine the radius of the boundary sphere. By default, only the first
flags everything; the second selection is there if one wants to remove
some part of the system to determine the radius of the boundary sphere
(such as a large part of a protein in an active site simulation).
For bulkd water sphere simulations, the first atom selection for should
be "select type OH2 end". The second atoms selection is optional and
could be "select type OH2 end" or could be "select (.not. type H*) end".
In NO CASE should the second selection includes the water hydrogens, since
the results were NOT parametrized for this selection.
11) BHEL key word
Stands for defining the boundary of the primary shell model as described in
Beglov & Roux, Biopolymers 35: 171-178 (1995). This method is useful
to provide one layer of solvent around a flexible polypeptide.
The selection should be that of the protein or peptide heavy atoms only.
12) SHEL key word
Stands for defining the solvent heavy atoms for the primary shell model.
Other options allow to modify the effective force reference (analogous to
the pressure (FREF).
Examples of MMFP GEO subcommnads
1) To setup a harmonic spherical restraint on all oxygens around the origin
(by default is harmonic potential and a sphere centered at the origin)
MMFP
GEO force 100.0 select type O* end
END
The entirely equivalent detailed command would be
MMFP
GEO sphere harm xref 0.0 yref 0.0 zref 0.0 force 100.0 select type O* end
END
2) The spherical quartic potential is very similary to SBOUND potential
(Suitable for a sphere of radius of 13.0 angstroms centered at the origin)
MMFP
GEO sphere quartic -
force 0.2 droff 13.0 p1 2.25 select type OH2 end
END
3) To impose a harmonic restraint on the center of mass of carbon alpha around
(x,y,z) = (1.0,2.0,3.0)
MMFP
GEO sphere RCM -
xref 1.0 yref 2.0 zref 3.0 -
force 10.0 droff 0.0 select type CA end
END
4) To apply a harmonic cylindrical tube constraint of 8 angstroms radius,
the axis of the cylinder is directed along ydir 1.0 and passes through the
point: xref=4.0,yref=5.0,z=6.0)
MMFP
GEO cylinder -
xref 4.0 yref 5.0 zref 6.0 xdir 0.0 ydir 1.0 -
force 100.0 droff 8.0 select type CA end
END
5) To apply a planar harmonic constraint with normal in zdir 1.0
MMFP
GEO plane -
xref 7.0 yref 8.0 zref 9.0 zdir 1.0 -
force 100.0 droff 0.0 select type N* end
END
6) To fix the distance between the center of mass of two subset of atoms
(e.g., two domains of a protein, two amino acids, etc...)
MMFP
GEO sphere RCM distance -
harmonic symmetric force 10.0 droff 5.0 -
select bynu 1:10 end select bynu 11:20 end
END
7) To constrain the angle between the center of mass of 3 subset of atoms
(e.g., 3 domains of a protein, 3 amino acids, etc...)
MMFP
GEO sphere RCM angle -
harmonic symmetric force 1000.0 droff 5.0 -
select bynu 1:10 end select bynu 11:20 end select bynu 21:30 end
END
8) To constrain the dihedral angle between the center of mass of 4 subset of atoms
(e.g., 4 domains of a protein, 4 amino acids, etc...)
MMFP
GEO sphere RCM dihedral -
harmonic symmetric force 1000.0 droff 5.0 -
select bynu 1:10 end select bynu 11:20 end -
select bynu 21:30 end select bynu 31:40 end
END
9) To reset all GEO potentials to zero and deallocate the HEAP space
MMFP
GEO reset
END
MMFP Substitution Parameters
There are several different variables that can be substituted in
titles or CHARMM commands that are set by some of the MMFP commands
(*note miscom.doc). Here is a summary and description of each variable.
----------------------------------------------------------------------------
'GEO'
The total energy contribution of the GEO restraining potentials.
----------------------------------------------------------------------------
'XCM','YCM','ZCM'
The position of the center of mass of the last set of atom is returned.
----------------------------------------------------------------------------
'XCM2','YCM2','ZCM2'
The position of the center of mass of the second set of atoms is
returned if the key word DISTANCE or ANGLE or DIHEDRAL was issued.
----------------------------------------------------------------------------
'XCM3','YCM3','ZCM3'
The position of the center of mass of the third set of atoms is
returned if the key word ANGLE or DIHEDRAL was issued.
----------------------------------------------------------------------------
'XCM4','YCM4','ZCM4'
The position of the center of mass of the fourth set of atoms is
returned if the key word DIHEDRAL was issued.
----------------------------------------------------------------------------
'RGEO'
The distance/angle/dihedral used in the last potential calculation
is returned. Set if a MMFP constraint with the keyword DIST or ANGLE
or DIHEDRAL was used.
----------------------------------------------------------------------------
'RADI'
The instantaneous sphere radius for the SSBP method.
----------------------------------------------------------------------------
Future developments:
1. The SSBP potential will be implemented for active site solvation (in
which a large part of the protein lies outside the spherical region).
2. A primary shell model for the solvation of polypeptides will be
implmented in the coming year. For details, see Beglov & Roux, Biopol.
(1995, in press).
The method is used for providing a first shell of waters around a
markedly non-spherical system. The boundary potential is flexible and
variable. It adapts dynamically to the shape of the polypeptide during a
dynamics.
NIH/DCRT/Laboratory for Structural Biology
FDA/CBER/OVRR Biophysics Laboratory
Modified, updated and generalized by C.L. Brooks, III
The Scripps Research Institute